※ 引述《ok456 (ooxx)》之銘言：
: 我想要求inverter的noise margin
: 查了manual
: 有一類似的example
: .MEAS DC result find v(in) when deriv v(out)= …
: 我稍微修改為
: .meas dc margin find v(output) when deriv v(output)=-1
: 但是一直job aborted
: .lis只會跟你說這一行有錯
: 亂try了好幾個版本　都沒有用
: 想請問各位版上高手 應該要如何修正呢?
: 謝謝!

想當初你的問題我也辛苦一段時間，底下是我目前對於VIL, VIH, VOL, VOH, NMH, NML
的求法，給你參考。

你的方法應該是我第二種求法。


* VIL, VIH, VOL, VOH, NMH, NML measurement
.global gnd vdd
.option post brief runlvl=5
.option nomod acct post=1 nopage
.option scale=1e-6

****Library model,simplified circuit and node initial file******
.prot
.lib './XXXX.l(自己的lib檔)' TT
.unprot

************************************
vvdd vdd 0 vcc
vgnd gnd 0 0
.param vcc=3.0v
.temp 25
************************************

.subckt inv Y A lp=0.35 wp=0.3 ln=0.3 wn=0.3
MN0 Y A gnd gnd NL w=wn l=ln
MP0 vdd A Y vdd PL w=wp l=lp
.ends inv
x1 2 1 inv wp=2.12 wn=0.82
x2 4 3 inv wp=2.12 wn=0.82
vx 3 1 0.01
vin 1 0 dc 0
*********************************************************************
.DC vin 0 3 0.01
***********************************************************************^
***********底下是求斜率等於負一(依書上Vil與Vih定義)
.measure dc voh find v(2) at 0
.measure dc vol find v(2) at 3
.measure dc vil find v(1) when par '(v(4)-v(2))/0.01'=-1 cross=1
.measure dc vih find v(1) when par '(v(4)-v(2))/0.01'=-1 cross=2
.measure dc NMH param='voh-vih'
.measure dc NML param='vil-vol'

*****底下是另一種求法，直接用hspcie裡的微分參數DERIV()~

.MEASURE DC VIL1 FIND V(1) WHEN DERIV('V(2)')=-1 cross=1
.MEASURE DC VIH1 FIND V(1) WHEN DERIV('V(2)')=-1 cross=2
.MEASURE DC VOHU FIND V(2) WHEN DERIV('V(2)')=-1 cross=1
.MEASURE DC VOLU FIND V(2) WHEN DERIV('V(2)')=-1 cross=2
.measure dc NML1 param='VIL1-VOLU'
.measure dc NMH1 param='VOHU-VIH'
.end


底下附上兩種sim出來的結果，好像略有差異。
個人覺得第二種的NML與NMH比較符合書上的定義。
都給你參考，因為要考慮NMOS是是depltion or enhancement load

.TITLE '* vil, vih, vol, voh, nmh, nml measurement'
voh=3.0
vol=0
vxil=1.1226
vih=1.6526
nmh=1.3474
nml=1.1226

vohu=2.7774
volu=0.1932
vil1=1.1326
vih1=1.6626
nml1=0.9394
nmh1=1.1248

--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 203.66.222.12